استراتيجية بولينجر باندز الموجهة

تعريف

يحدد «اتجاه الإستراتيجية» أنواع الأوامر التي يُسمح للاستراتيجية بإنشائها. إذا كانت قيمة الإعداد هي 0، فيمكن أن تكون طويلة وقصيرة. إذا كان الإعداد هو -1، فيمكن أن يكون قصيرًا فقط وإذا كان 1 يمكن أن يستمر طويلاً فقط. يدخل اتجاه استراتيجية بولينجر باند مركز شراء عندما يعبر الرمز أسفل النطاق السفلي من نطاقات بولينجر، ومركز بيع إذا تجاوز الرمز النطاق العلوي. ولكن تذكر أنه في إعدادات الإستراتيجية يمكنك ضبط الاتجاه ليكون شراء أو بيعًا أو كليهما.

عملية الحساب

Pine Script

//@version=5
strategy("Bollinger Bands Strategy directed", overlay=true)
source = close
length = input.int(20, minval=1)
mult = input.float(2.0, minval=0.001, maxval=50)
direction = input.int(0, title = "Strategy Direction", minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))
basis = ta.sma(source, length)
dev = mult * ta.stdev(source, length)
upper = basis + dev
lower = basis - dev
if (ta.crossover(source, lower))
  strategy.entry("BBandLE", strategy.long, stop=lower, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandLE")
else
  strategy.cancel(id="BBandLE")
if (ta.crossunder(source, upper))
  strategy.entry("BBandSE", strategy.short, stop=upper, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandSE")
else
  strategy.cancel(id="BBandSE")
//plot(strategy.equity, title="equity", color=color.red, linewidth=2, style=plot.style_areabr)

خاتمة

تم إنشاء إستراتيجية بولينجر باندز الموجهة للشراء أو البيع عندما يكون الرمز ممتدًا بشكل شديد من متوسط سعره. مثلًا، يمكن توجيه الاستراتيجية للشراء إذا انخفض الرمز إلى ما دون نطاق بولينجر السفلي أو البيع إذا تجاوز نطاق بولينجر العلوي. قد ينظر بعض المتداولين إلى هذا على أنه ارتداد من المتوسط لأنه يتم إنشاء بولينجر باندز باستخدام الانحراف المعياري لمتوسط سعر الرمز. تذكر أن الاستراتيجية موجهة وفي الإعدادات يمكنك التحكم في القيمة، أي. إذا كانت 0 فستكون طويلة وقصيرة. إذا كان الإعداد هو -1، فيمكن أن يكون قصيرًا فقط وإذا كان 1 يمكن أن يستمر طويلاً فقط.